LOAD

LOAD
Syntax:	LOAD [<Programmname>] [,<Gerätenummer>] [,<Sekundäradresse>]
Parameter
<Programmname>: Zeichenketten-Ausdruck, der den Programmnamen enthält
<Gerätenummer>: numerischer Ausdruck im Wertebereich von 1 bis 255
<Sekundäradresse>: numerischer Ausdruck im Wertebereich von 0 bis 255
Einordnung
Typ:	Anweisung
Kontext:	BASIC-Editor
Aufgabe:	Programme in den RAM-Speicher laden
Abkürzung:	lO
Token:	$93 (147)
Verwandte Befehle
SAVE, VERIFY

Anmerkung: Dieser Artikel beschreibt den BASIC-Befehl LOAD unter BASIC V2 des Commodore 64.

Mit dem BASIC-Befehl LOAD werden Programmdateien (PRG), z.B. BASIC- oder Maschinensprache-Programme, von Datasette oder Diskette in den RAM-Speicher geladen. Bevor diese bearbeitet werden oder mit BASIC-Befehlen wie RUN oder SYS ausgeführt werden können.

Programmname

Der Programmname bzw. Dateiname, als Zeichenkettenausdruck verstanden, wählt die zu ladende Datei am Datenträger aus. Speziell bei Floppy-Laufwerken können auch Jokerzeichen wie '*' oder '?' eingesetzt werden. Die Eingabe von LOAD "0:*",8 bzw. LOAD ":*",8 lädt von Gerät Nr. 8 und Laufwerk 0 (ein Selektor im Falle von Doppellaufwerken) die erste PRG-Datei laut Disketteninhaltsverzeichnis. Bei einer Datasette bewirkt die Angabe eines leeren Dateinamens das Laden der nächsten Datei am Band (quasi eine Kurzform für "*").
Bei LOAD "*",8 wird unmittelbar nach dem Einlegen der Diskette ins Laufwerk oder nach einer Floppy-Initialisierung die erste PRG-Datei oder sonst die zuletzt geladene Datei geladen. In der gewöhnlichen Form kann beispielsweise mit LOAD "ABC*",8 der erste Dateiname beginnend mit ABC geladen werden.
Der Spezialfall LOAD "$",8 bewirkt das Abrufen des Disketteninhaltsverzeichnisses, das sich wie ein normales BASIC-Programm mittels LIST-Befehl sichten lässt und dabei ein im Speicher vorhandenes BASIC-Programm zerstört.
Die BASIC-Fehlermeldung ?FILE NOT FOUND ERROR wird ausgegeben, wenn der Dateiname des Programms nicht existiert oder es keine Programmdatei ist. Die Systemvariable ST kann spezifische Fehlerbits gesetzt haben und bei Diskettenlaufwerken weist der Fehlerkanal zusätzlich eine entsprechende Fehlermeldung auf.

Gerätenummer

Mit der Gerätenummer wird bestimmt, ob ein Programm von Datasette (Gerätenummer 1), Diskette (Gerätenummer 8-30, norm. erstes Diskettenlaufwerk 8 und zweites Diskettenlaufwerk 9 usw.) oder einem anderen Datenträger wie z.B. einer Festplatte eingelesen wird. Fehlt die Gerätenummer, so wird auf das im Betriebssystem (KERNAL) verankerte Standardeingabegerät (beim originalen Commodore-Betriebssystem die Datasette) zugegriffen. Geräteadressen im Bereich von 4-62 führen für nicht vorhandene Geräte zur Fehlermeldung ?DEVICE NOT PRESENT ERROR. Werte 0, 2 und 3 rufen ein ?ILLEGAL DEVICE ERROR hervor, während Werte außerhalb des Bereichs 0 bis 255 mit der Fehlermeldung ?ILLEGAL QUANTITY ERROR abbrechen.

Sekundäradresse

Durch die Angabe der Sekundäradresse 1 (LOAD "NAME",8,1) wird ein Programm absolut geladen, d.h. es wird an die Stelle im Speicher geladen, die der gespeicherten Ladeadresse entspricht (z.B. durch Speicherung mit dem BASIC-Befehl SAVE). Dies ist z.B. für Maschinenspracheprogramme erforderlich, die nur an einer bestimmten Stelle im Speicher ausführbar sind und dabei das gerade aktive BASIC-Programm nicht überschreiben sollen.
Fehlt die Sekundäradresse oder ist sie Null, wird das Programm immer an den BASIC-Anfang (beim C64 i.d.R. die Speicherstelle 2049 bzw. $0801 des RAMs) geladen.

Intern öffnet LOAD die jeweilige Datei vom Laufwerk (beim seriellen Zugriff) immer mit Sekundäradresse $60/96. Der Sekundäradressen-Parameter von LOAD wird also dem Laufwerk nicht übermittelt und nur genutzt, um die Behandlung der Ladeadresse festzulegen.

Hinweise

• Im Direktmodus ausgeführt schließt LOAD alle offenen Dateien, führt den BASIC-Befehl CLR aus und setzt VARTAB, ARYTAB und STREND (siehe Speicherbelegung) auf das Ende der geladenen Datei. Falls kein BASIC-Programm geladen wurde, kann das (ohne z.B. nachfolgendes NEW) zu unerwarteten Ergebnissen führen, z.B. zum Fehler ?OUT OF MEMORY ERROR, wenn die nachgeladenen Daten über $9FFF enden.
• Im Programmmodus ausgeführt wird von LOAD der Stapelspeicher (Stack) gelöscht, dabei aber das BASIC-Programmende VARTAB nicht geändert. Nach dem Laden der Datei wird Programm automatisch ähnlich RUN wieder bei der ersten Zeile gestartet (siehe Beispiele). Sämtliche Variablen bleiben erhalten, sofern die nachgeladenen Daten außerhalb des BASIC-Speichers liegen oder ein ggf. nachgeladenes BASIC-Programm kürzer ist als das nachladende Programm. Wurde ein BASIC-Programm nachgeladen, das länger als das nachladende Programm ist, wird der Variablenspeicher überschrieben und die Variablen korrumpiert.
  • Wegen dieser Einschränkungen werden per RUN zu startende Programme normalerweise nicht direkt per LOAD nachgeladen; ein üblicher Trick ist es, LOAD"...",8 und RUN per PRINT auf den Bildschirm zu schreiben, zweimal RETURN per POKE in den Tastaturpuffer zu schreiben und das Programm zu beenden. Die zwei RETURNs laden und starten dann das andere Programm automatisch mit dem Direktmodus-LOAD.

Im Gegensatz zum direkten Ansprechen der Programmdateien mit dem Dateinamen bei Disketten reicht es beim Umgang mit der Datasette, für den Zugriff auf Datenkassetten den BASIC-Befehl LOAD einzugeben oder die Tasten SHIFT +RUN/STOP  zu drücken. Danach kann die <PLAY>-Taste der Datasette gedrückt werden und es wird die erste gefundene Datei eingelesen. Jedes dabei gefundene Programm wird zuerst nach einigen Sekunden mit FOUND Dateiname angezeigt, bevor es geladen wird. Mit der Taste C=  (Commodore-Logo) oder auch SPACE  (Leertaste) wird der Ladevorgang der aktuellen Datei unverzüglich fortgesetzt, bevor die Pause mit der Programmfundanzeige automatisch beendet wird. Die Datasette stoppt selbsttätig, wenn das Programm komplett eingelesen ist oder das Ende des Bandes erreicht ist. Während des Ladens von Programmen von Kassette wird der Bildschirm bei der originalen Commodore-Laderoutine abgeschaltet. Dies macht das Commodore-Betriebssystem beim Einlesen von Disketten oder von anderen Datenträgern nicht.

Die maximale sinnvolle Länge - LOAD selbst schränkt die Länge nicht ein - eines per LOAD geladenen und mit RUN gestarteten Programms beträgt im Normalfall etwa 51 KByte bzw. 202 Blöcke. Dabei handelt es sich um den Speicherbereich von $0801 bis $CFFF, wobei die obere Grenze der I/O-Bereich ab $D000 (siehe Speicherbelegungsplan) vorgegeben wird. Daten, die in den Bereich von $A000 bis $BFFF gelangen, werden von LOAD dabei in das RAM "unter" das BASIC-ROM geladen und sind von BASIC aus nicht sichtbar. Entsprechend sind Programme dieser Länge nicht selten Maschinenspracheprogramme oder auch kombiniert mit Daten, die z.B. mittels Assembler oder Compiler erzeugt wurden und auch dann auch von Maschinespracheprogrammen verwendet werden. Die maximale Länge eines BASIC-Programms beträgt in der Praxis unter 39 KByte bzw. 153 Blöcke (bis $9FFF), typischerweise weniger, da im gleichen Speicherbereich auch die Variablen liegen müssen.

Beispiele

LOAD "DATEINAME",8

Lädt das Programm von Diskette im 1. Diskettenlaufwerk, mit Gerätenummer 8.

LOAD "DATEINAME",9,1

Lädt das Programm "absolut" von Diskette im 2. Diskettenlaufwerk, mit Gerätenummer 9.

LOAD FILE$,1,1

Lädt das Programm, dessen Name in Zeichenkette FILE$ abgelegt ist, absolut von Datasette.

10 REM MC-BIBLIOTHEK LADEN
20 IF PEEK(49152)<>169 THEN LOAD "LIB",8,1
30 SYS 49152 : REM BIBLIOTHEK INITIALISIEREN

Lädt ein zum BASIC-Programm gehörende Hilfsbibliothek, die z.B. per SYS aufrufbar Hilfsfunktionen enthält. Diese wird nur geladen, wenn sie sich noch nicht im Speicher befindet. Erkannt wird dies hier einfach am ersten Byte des geladenen Programms, dass hier mit dem Byte-Wert 169 angenommen wird.

Einfaches Vorladeprogramm

10 REM JUMP&RUN-SPIEL VORLADEPROGRAMM 
20 A=A+1: PRINT "PROGRAMMTEIL" A
30 IF A=1 THEN LOAD "MUSIK",8,1
40 IF A=2 THEN LOAD "SPRITES",8,1
50 IF A=3 THEN LOAD "GRAFIK",8,1
60 IF A=4 THEN LOAD "LEVEL1",8,1
70 ...

Bei diesem Vorladeprogramm werden die Daten (MUSIK, SPRITES, GRAFIK, LEVEL1) von dem Diskettenlaufwerk mit der Gerätenummer 8 absolut in den Speicher geladen und dann das Programm ab Zeile 70 fortgesetzt. Wie in den Hinweisen erwähnt, lässt sich ein (längeres) BASIC-Programm auf diese Weise allerdings nicht nachladen.

Vorladeprogramm mit Ladeanzeige

0  REM JUMP&RUN-SPIEL VORLADEPROGRAMM
10 D=8: N=4: DATA "MUSIK", "SPRITES", "GRAFIK", "LEVEL1"
20 A = A+1: REM VARIABLE A BLEIBT NACH LOAD erhalten
30 FOR I=1 TO A: READ F$: NEXT
40 IF A=1 THEN PRINT CHR$(147)"BITTE WARTEN PROGRAMM WIRD GELADEN..."
50 PRINT INT(100*A/N)"%", F$: REM PROZENTANGABE UND DATEINAME
60 LOAD F$,D,1 : REM TEIL LADEN
70 ...

Im Wesentlichen wie das vorige Beispiel, allerdings generischer und mit Fortschrittsanzeige:
Die Dateinamen sind in der DATA-Zeile enthalten. Die Gerätenummer befindet sich in der Variable D.
Implementierungsanmerkungen:

• Die Variable N speichert die Anzahl der zu ladenden Dateien.
  
• Jeder Ladeschritt wird mit einer Fortschrittsanzeige als Prozentwert begleitet (der nach dem Laden des Teils erreicht wird).
• Der vom LOAD erzeugte Neustart des Programm lässt die Variablen unberührt, aber der DATA-Zeiger wird stets zurückgesetzt. Daher das Einlesen des Dateinamens übereine Schleife abhängig von Variable A.
• In Zeile 50 wird nach der Prozentzahl der Dateiname angezeigt, was natürlich auch unterbleiben kann (", F$" weglassen).
• Auch hier können keine BASIC-Programme nachgeladen werden, die länger als das Vorladeprogramm sind.

BASIC V2-Befehle des Commodore 64

ABS | AND | ASC | ATN | CHR$ | CLOSE | CLR | CMD | CONT | COS | DATA | DEF | DIM | END | EXP | FN | FOR | FRE | GET | GET# | GOSUB | GOTO | IF | INPUT | INPUT# | INT | LEFT$ | LEN | LET | LIST | LOAD | LOG | MID$ | NEW | NEXT | NOT | ON | OPEN | OR | PEEK | POKE | POS | PRINT | PRINT# | READ | REM | RESTORE | RETURN | RIGHT$ | RND | RUN | SAVE | SGN | SIN | SPC | SQR | STATUS/ST | STEP | STOP | STR$ | SYS | TAB | TAN | THEN | TIME/TI | TIME$/TI$ | TO | USR | VAL | VERIFY | WAIT