Das Haus des Magiers/Listing
Aus C64-Wiki
Zur Navigation springenZur Suche springen<< zurück zu Das Haus des Magiers
1 rem
2 rem
3 rem
4 rem
5 rem
6 rem
7 rem
8 rem
9 rem
10 dim f%(4,4,3),ob$(65),be$(16),ob(65),ag(65),f(96),fa(16),fb(32):xx=56329
13 poke53280,6:poke53281,6:poke646,14:tu=0:t1=0
14 for i=1 to 65:ag(i)=0:next
15 print chr$(147)"{down}{rvon} moment ich muss mich erst informieren ,{rvof}"
17 poke 54272+24,0
20 for i=1 to 65:read ob$(i):next
30 for i=1 to 16:read be$(i):next
40 data theke,schublade,schluessel,tisch,herd,schrank,topf,schachtel,pille
50 data regal,apfel,salbe,knopf,bild,kiste,tresor,zettel,regal,schrank,tisch
60 data buch,badewanne,handtuch,fenster,schachtel,streichhoelzer,leiter
70 data messer,bild,fenster,tisch,stuhl,schrank,flasche,treppe,treppe,waechter
80 data waechter,waechter,waechter,tuer
81 data tisch,kaefig,brieftaube,truhe,zettel,schrank,gewehr,kiste,sack
82 data schrank,schluessel,pistole,keule,regal,knopf,tuer
83 data magier,gnom,stock,brecheisen,maedchen,xxxx,xxxxxx,xxxxxx
90 data schau,nimm,verliere,oeffne,lies,iss,trink,benutze,verjage,druecke
100 data befreie,verwandle,save,verzaubere,hilfe,list
110 for i=1 to 48:read x:read y:read z:read q
120 f%(x,y,z)=q
130 next
140 data 1,1,2,1,2,1,2,2,3,1,2,3,4,1,2,4,1,2,2,5,2,2,2,6,3,2,2,7,4,2,2,8
150 data 1,3,2,9,2,3,2,10,3,3,2,11,4,3,2,12,1,4,2,13,2,4,2,14,3,4,2,15,4,4,2,16
160 data 1,1,1,17,2,1,1,18,3,1,1,19,4,1,1,20,1,2,1,21,2,2,1,22,3,2,1,23,4,2,1,24
170 data 1,3,1,25,2,3,1,26,3,3,1,27,4,3,1,28,1,4,1,29,2,4,1,30,3,4,1,31,4,4,1,32
180 data 1,1,3,33,2,1,3,34,3,1,3,35,4,1,3,36,1,2,3,37,2,2,3,38,3,2,3,39,4,2,3,40
190 data 1,3,3,41,2,3,3,42,3,3,3,43,4,3,3,44,1,4,3,45,2,4,3,46,3,4,3,47,4,4,3,48
210 :
220 v=53248:poke 2042,13:poke 2043,14:poke 2044,15:poke 2045,11
230 for n=0 to 62:read q:poke 832+n,q:next
231 for n=0 to 62:read q:poke 49280+n,q:next
232 for n=0 to 62:read q:poke 49216+n,q:next
233 for n=0 to 62:read q:poke 704+n,q:next
234 for n=0 to 62:read q:poke 49152+n,q:next
240 poke v+4,80:poke v+5,121
241 poke v+6,200:poke v+7,200:poke v+29,56:poke v+23,48
242 poke v+41,1:poke v+42,7:poke v+44,0
243 poke v+8,120:poke v+9,150
244 poke v+10,120:poke v+11,150
250 data 0,0,0,0,126,0,1,129,192,7,68,48,14,136,24,8,136,8,0,136,4
251 data 0,204,4,0,68,4,0,36,4,0,36,4,0,34,8,0,34,8,0,36,8,0,108,16
252 data 16,204,32,12,0,192,3,255,0,0,96,0,0,0,0,0,0,0
253 data 0,28,0,0,127,0,1,255,192,3,255,224,0,31,144,3,227,140,14,127,227,31
254 data 255,192,15,191,192,0,61,128,3,255,0,3,254,0,1,254,192,0,63,224
255 data 0,31,240,0,111,240,0,119,224,0,123,192,0,31,128,1,123,192,1,123,192
256 data 0,14,0,0,30,0,0,31,224,1,255,32,0,72,128,0,123,128,0,19,0,0,31,0
257 data 0,33,0,0,30,0,4,12,0,2,255,224,1,127,224,0,63,160,0,191,96,0,78,192
258 data 0,39,128,0,56,0,0,63,0,0,41,0,1,225,224
259 data 0,28,0,0,127,0,0,255,128,0,190,128,1,217,192,1,247,192,1,247,192
260 data 1,119,64,1,255,64,1,65,64,0,127,0,3,190,224,7,221,240,15,190,248
261 data 15,127,120,15,127,120,31,190,252,31,221,120,31,54,124,14,54,60
262 data 20,117,20
263 data 1,226,128,3,243,128,3,236,176,3,248,32,7,255,48,15,223,136
264 data 27,239,8,17,240,12,41,252,3,72,120,2,0,60,2,0,236,0,0,176
265 data 0,0,223,192,0,224,96,1,252,0,3,254,0,0,88,0,0,216,0,1,152,0,1,220,0
266 for n=320 to 415:read f(n-320):next
267 data 0,0,0, 58,0,0, 69,7,81, 58,6,133, 78,7,81, 58,0,0, 87,6,133, 58,0,0
268 data 78,7,81, 58,0,0, 69,0,0, 0,0,0,58,6,133, 0,0,0, 58,6,133, 0,7,81
269 data 0,0,0, 58,0,0, 69,8,180, 58,8,55, 58,0,0, 78,8,180, 87,8,180, 58,0,0
270 data 78,5,207, 58,0,0, 69,5,207, 0,0,0, 65,6,133, 0,0,0, 58,6,133,0,0,0
271 si=54272:w=si+4
280 for i=1 to 62:read ob(i):next
281 data 14,0,0,13,9,9,0,0,0,5,0,0,10,6,6,0,0,7,7,7,0,3,3,3,2,0,1,11,12,12,15
282 data 15,16,0,8,4,0,0,0,0,8,33,33,0,40,0,43,0,44,0,45,0,0,46,48,48,0,0,0,0
283 data 28,29
284 za$(1)="zapzarapp":za$(2)="huibuh":za$(3)="hokuspokus":za$(4)="hulabula"
285 for n=0 to 15:read a:fa(n)=a:next
286 for n=0 to 29:read a:fb(n)=a:next
287 data 16,109,14,162,16,109,14,162
288 data 16,109,14,162,13,208,15,129
289 data 15,123,15,123,13,203,13,203,12,73,12,73
290 data 0,0,0,0,13,203,12,73,10,242,12,73,10,242
291 data 9,192,8,176
320 print chr$(147):poke 646,1
325 print"{down}{down}{down}{down}{down} **********************************"
326 poke v+21,4:print"{down}{down}"
330 print tab(10)"as haus des magiers"
340 print tab(7)"{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}{CBM-U}"
350 print tab(7)"{down}(c) 1985 by haegar rainerle "
360 print"{down}{down} **********************************"
362 for i=0 to 6
363 forp=55299to55335:pokep+240,0:pokep+640,0:pokep+239,1:pokep+639,1:next:next
370 poke 646,0:poke v+21,0:print chr$(147)
371 for n=0 to 62:poke 832+n,peek(49152+n):next
372 poke v+4,110:poke v+5,170
374 poke v+23,52:poke v+29,60
375 poke 646,7:print"moechtest du":print
376 print"ein {rvon}n{rvof}eues spiel beginnen ?":print
377 print"ein {rvon}a{rvof}ltes spiel fortsetzen ?"
378 geta$:ifa$=""then 378
379 if a$="a"then 4300
380 poke v+21,3:print chr$(147):poke 646,0
390 print tab(5)"das haus des magiers
400 print tab(5)"DDDDDDDDDDDDDDDDDDDD"
410 poke 646,7
420 print:
430 print tab(5)"bei diesem adventure musst du
440 print tab(5)"mehrere aufgaben loesen, die
450 printtab(5)"sich aus dem spielverlauf
460 printtab(5)"ergeben.
470 printtab(5)"{down}je nachdem
480 printtab(5)"- ob du die aufgaben loest,
490 printtab(5)"- wie du sie loest, und
500 printtab(5)"- wieviele der aufgaben du
510 printtab(7)"loest
520 printtab(5)"bekommst du am ende des spiels
530 printtab(5)"eine wertung in prozent(%).
540 printtab(30)"{down}{down}{down}{down}{down}{rvon}return{rvof}"
550 get a$:if a$=""then 550
560 print chr$(147):poke 646,0
570 printtab(5)"das haus des magiers
590 printtab(5)"DDDDDDDDDDDDDDDDDDDD":poke 646,7
600 printtab(5)"{down}die befehle, mit denen du dich
610 printtab(5)"durch das spiel bewegst, bestehen
620 printtab(5)"in der regel aus zwei worten
630 printtab(5)"(z.b. nimm messer)
640 printtab(5)"oder einer richtungsangabe.
650 printtab(5)"hierbei genuegt der anfangs-
660 printtab(5)"buchstabe.
670 printtab(5)"{down}{rvon}n{rvof}ord, {rvon}s{rvof}ued, {rvon}w{rvof}est
680 printtab(5)"{down}{rvon}o{rvof}st, {rvon}h{rvof}och, {rvon}r{rvof}unter
685 print"{down}schau nimm verliere oeffne lies iss"
686 print"{down}trink verjage druecke befreie"
687 print"{down}verwandle save verzaubere list"
690 printtab(30)"{down}{down}{rvon}return{rvon}"
700 get a$:if a$=""then 700
710 x=2:y=4:z=2
720 print chr$(147)
740 printtab(5)"du bist mit deiner kutsche unter-
750 printtab(5)"wegs. draussen tobt ein unwetter.
760 printtab(5)"durch die unachtsamkeit deines
770 printtab(5)"kutschers bricht ein rad.
780 printtab(5)"durch den regen hindurch siehst
790 printtab(5)"du ein haus, wo du dich aufwaermen
800 printtab(5)"willst, waehrend der kutscher
810 printtab(5)"den schaden behebt.
820 printtab(5)"{down}du gehst auf das haus zu und
830 printtab(5)"trittst ein."
840 printtab(30)"{down}{down}{down}{down}{down}{down}{down}{down}{rvon}return{rvof}"
850 get a$:if a$=""then850
860 print chr$(147):poke646,3:ti$="000000"
870 ob(51)=int(4*rnd(1))+17
875 ob(28)=int(7*rnd(1))+9:if ob(28)=14 then ob(28)=16
880 za=int (4*rnd(1))+1
1030 ze=0:zw=5:q=0
1032 for n=0 to 62:poke 960+n,peek(49216+n):next
1033 for n=0 to 62:poke 896+n,peek(49280+n):next
1034 r$(1)="keller":r$(2)="erdgeschoss":r$(3)="1.stock"
1035 print chr$(147):poke v+21,0:ze=ze+1
1036 zw=zw+1:if zw>8 then zw=5
1037 ob(37)=zw:ob(38)=zw-4:ob(58)=zw+37:ob(59)=2*zw+30:ob(39)=zw+12:ob(40)=4*zw
1040 print"du befindest dich im ";r$(z)
1041 gosub 9000
1042 gosub 50000
1043 if f%(x,y,z)=ob(37)or f%(x,y,z)=ob(38)then poke v+43,1:poke v+21,16
1044 if f%(x,y,z)=ob(59)then poke v+42,7:poke v+21,8
1045 if f%(x,y,z)=ob(58)then poke v+21,32
1046 if f%(x,y,z)=ob(58)and f%(x,y,z)=ob(59)then poke v+21,40
1047 if f%(x,y,z)=ob(39)or f%(x,y,z)=ob(40)then poke v+43,0:poke v+21,16
1048 if f%(x,y,z)=ob(62)then poke v+21,4
1049 :
1050 print"{home}{down}{down}{down}du siehst:"
1060 for i=1 to 65
1070 if ob(i)=f%(x,y,z)thenprintob$(i)
1080 next
1090 ko$=""
1091 ifob(59)=f%(x,y,z)andag(28)=1thenprint"der "ob$(59);"hat dir dein ";ob$(28)
1092 ifob(59)=f%(x,y,z)andag(28)=1thenprint"versteckt.":q=q-1:ob(28)=int(5*rnd(1))+40
1093 if ob(59)=f%(x,y,z)and ag(28)=1 then ag(28)=0
1095 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
1096 iff%(x,y,z)=ob(39)or f%(x,y,z)=ob(40)then gosub 60400
1098 if qm>0 then qm=qm-1:if qm=0 then q=q+2
1099 if q>4 then 43000
1100 iff%(x,y,z)=ob(37)orf%(x,y,z)=ob(38)orf%(x,y,z)=ob(58)thengosub60400
1101 input"{down}anweisung";ko$
1102 fori=37to40:ifob(i)=f%(x,y,z)andleft$(ko$,7)<>be$(9)then1105
1103 next
1104 goto 1106
1105 ifleft$(ko$,5)<>be$(13)then 30000
1106 ifob(58)=f%(x,y,z)andleft$(ko$,9)<>be$(12)then1108
1107 goto 1110
1108 ifleft$(ko$,10)<>be$(14)then 30000
1110 if ko$="n"then 2000
1120 if ko$="s"then 2100
1130 if ko$="w"then 2200
1140 if ko$="o"then 2300
1150 if ko$="h"then 2400
1160 if ko$="r"then 2500
1165 i=0
1170 i=i+1:if i>16 then 4100
1180 if be$(i)=left$(ko$,(len(be$(i))))then 1200
1190 goto 1170
1200 onigoto2600,2700,2800,2900,3000,3110,3200,3300,3400,3500,3600,3700,3800
1210 on(i-13)goto 3900,4000,4200
2000 rem *** norden ***
2001 iff%(x,y,z)=7orf%(x,y,z)=9orf%(x,y,z)=10theny=y-1:goto1035
2005 if f%(x,y,z)=8 then 2080
2010 iff%(x,y,z)=12orf%(x,y,z)=13orf%(x,y,z)=14orf%(x,y,z)=16theny=y-1:goto1035
2011 iff%(x,y,z)=21orf%(x,y,z)=22orf%(x,y,z)=27theny=y-1:goto1035
2012 iff%(x,y,z)=30orf%(x,y,z)=31orf%(x,y,z)=32theny=y-1:goto1035
2020 iff%(x,y,z)=37orf%(x,y,z)=38orf%(x,y,z)=39orf%(x,y,z)=40theny=y-1:goto1035
2030 iff%(x,y,z)=41orf%(x,y,z)=43orf%(x,y,z)=46orf%(x,y,z)=47theny=y-1:goto1035
2060 poke 646,1
2070 print"{down}du kannst nicht durch waende laufen!":goto40000
2080 iftu=0thenpoke646,1:print"die tuer ist verschlossen":goto40000
2090 y=y-1:goto 1035
2100 rem *** sueden ***
2101 iff%(x,y,z)=3orf%(x,y,z)=4orf%(x,y,z)=5orf%(x,y,z)=6theny=y+1:goto1035
2110 iff%(x,y,z)=8orf%(x,y,z)=9orf%(x,y,z)=10orf%(x,y,z)=12theny=y+1:goto1035
2120 iff%(x,y,z)=14then5110
2130 iff%(x,y,z)=33orf%(x,y,z)=34orf%(x,y,z)=35orf%(x,y,z)=36theny=y+1:goto1035
2140 iff%(x,y,z)=37orf%(x,y,z)=39orf%(x,y,z)=42orf%(x,y,z)=43theny=y+1:goto1035
2150 iff%(x,y,z)=44theny=y+1:goto1035
2160 iff%(x,y,z)=17orf%(x,y,z)=18orf%(x,y,z)=23theny=y+1:goto1035
2170 iff%(x,y,z)=26orf%(x,y,z)=27orf%(x,y,z)=28theny=y+1:goto1035
2190 print"{down}du kannst nicht durch waende laufen!":goto40000
2200 rem *** westen ***
2201 iff%(x,y,z)=2orf%(x,y,z)=3orf%(x,y,z)=7orf%(x,y,z)=11thenx=x-1:goto1035
2210 iff%(x,y,z)=12orf%(x,y,z)=14orf%(x,y,z)=15orf%(x,y,z)=16thenx=x-1:goto1035
2230 iff%(x,y,z)=35orf%(x,y,z)=36orf%(x,y,z)=38orf%(x,y,z)=42thenx=x-1:goto1035
2240 iff%(x,y,z)=46orf%(x,y,z)=47orf%(x,y,z)=48thenx=x-1:goto1035
2250 iff%(x,y,z)=19orf%(x,y,z)=20orf%(x,y,z)=22orf%(x,y,z)=23thenx=x-1:goto1035
2260 iff%(x,y,z)=24orf%(x,y,z)=27orf%(x,y,z)=28orf%(x,y,z)=31thenx=x-1:goto1035
2270 iff%(x,y,z)=32thenx=x-1:goto1035
2280 iff%(x,y,z)=30andt1=0thenprint"die tuer ist verschlossen!":goto40000
2285 iff%(x,y,z)=30andt1=1thenx=x-1:goto1035
2290 poke646,1:print"{down}du kannst nicht durch waende laufen!":goto40000
2300 rem *** osten ***
2301 iff%(x,y,z)=1orf%(x,y,z)=2orf%(x,y,z)=6orf%(x,y,z)=10thenx=x+1:goto1035
2310 iff%(x,y,z)=11orf%(x,y,z)=13orf%(x,y,z)=14orf%(x,y,z)=15thenx=x+1:goto1035
2320 iff%(x,y,z)=34orf%(x,y,z)=35orf%(x,y,z)=37orf%(x,y,z)=41thenx=x+1:goto1035
2330 iff%(x,y,z)=45orf%(x,y,z)=46orf%(x,y,z)=47thenx=x+1:goto1035
2340 iff%(x,y,z)=18orf%(x,y,z)=19orf%(x,y,z)=21orf%(x,y,z)=22thenx=x+1:goto1035
2350 iff%(x,y,z)=23orf%(x,y,z)=26orf%(x,y,z)=27orf%(x,y,z)=29thenx=x+1:goto1035
2360 iff%(x,y,z)=30orf%(x,y,z)=31thenx=x+1:goto1035
2390 poke646,1:print"{down}du kannst nicht durch waende laufen!":goto40000
2400 rem *** hoch ***
2401 iff%(x,y,z)=4orf%(x,y,z)=17orf%(x,y,z)=24thenz=z+1:goto1035
2410 poke646,1:print"hier geht's nicht nach oben!":goto40000
2500 rem *** runter ***
2501 iff%(x,y,z)=1orf%(x,y,z)=8thenz=z-1:goto1035
2510 iff%(x,y,z)=36thenz=z-1:goto1035
2520 poke646,1:print"hier geht's nicht nach unten":goto40000
2600 rem *** schau ***
2601 i=0
2610 i=i+1:if i>65 then 2630
2620 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then2640
2625 goto 2610
2630 poke646,1:print"nicht vorhanden":poke646,3:goto40000
2640 ifi=1ori=5ori=6ori=8thenprint"ich sehe etwas!":goto10000
2645 if i=24 or i=30 then 30000
2650 ifi=10ori=14ori=15ori=18thenprint"ich sehe etwas!":goto10000
2660 ifi=19ori=20ori=25ori=33ori=43thenprint"ich sehe etwas!":goto10000
2690 print"ich sehe nichts besonderes!":goto40000
2700 rem *** nimm ***
2701 i=0
2710 i=i+1:if i>65 then 2740
2720 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then2750
2730 goto 2710
2740 poke646,1:print"nicht vorhanden":poke646,3:goto40000
2750 ifi=1ori=4ori=5ori=6ori=10ori=16thenprint"dass uebersteigt doch wohl etwas"
2760 ifi=1ori=4ori=5ori=6ori=10ori=16thenprint"deine kraefte!":goto40000
2780 ifi=18ori=19ori=20ori=22ori=24ori=30thenprint"dass uebersteigt doch wohl etwas"
2790 ifi=18ori=19ori=20ori=22ori=24ori=30thenprint"deine kraefte!":goto40000
2791 ifi=42ori=45ori=47ori=49ori=51ori=55thenprint"dass uebersteigt doch wohl etwas"
2792 ifi=42ori=45ori=47ori=49ori=51ori=55thenprint"deine kraefte!":goto40000
2793 ifi=31ori=32ori=33ori=35ori=36thenprint"dass uebersteigt doch wohl etwas"
2794 ifi=31ori=32ori=33ori=35ori=36thenprint"deine kraefte!":goto40000
2797 q=q+1
2798 ifq>4thenprint"du kannst nicht soviel tragen!":q=4:goto40000
2799 print"ok.":ag(i)=1:ob(i)=0:goto40000
2800 rem *** verliere ***
2801 i=0
2810 i=i+1:ifi>65then2840
2820 ifright$(ko$,(len(ob$(i))))=ob$(i)andag(i)=1then2850
2830 goto 2810
2840 poke646,1:print"das hast du nicht dabei!":goto40000
2850 print"ok.":ob(i)=f%(x,y,z):ag(i)=0:q=q-1:goto40000
2900 rem *** oeffne ***
2901 i=0
2910 i=i+1:ifi>65then2940
2911 ifright$(ko$,12)="eingangstuer"andf%(x,y,z)=14theninput"womit";wo$:goto2933
2912 ifright$(ko$,4)="tuer"andf%(x,y,z)=30theninput"womit";wo$:goto2936
2920 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then2941
2930 goto2910
2932 goto2940
2933 ifwo$=ob$(52)andag(52)=0thenprint"den besitzt du nicht":goto40000
2934 ifwo$=ob$(52)andag(52)=1thenprint"meinen glueckwunsch, du bist draussen!":z=5
2935 fori=0to1000:next:goto39000
2936 ifwo$=ob$(61)andag(61)=1thenprint"ok. die tuer ist offen":t1=1:goto40000
2937 ifwo$<>ob$(61)thenprint"damit geht es nicht":goto40000
2940 poke646,1:print"nicht vorhanden":goto40000
2941 ifi=43ori=40ori=43ori=44ori=45ori=47ori=49ori=51then2980
2950 ifi=2ori=6ori=7ori=8ori=15ori=16ori=24ori=30ori=33ori=34then2980
2951 ifi=41andtu=0theninput"womit";wo$
2954 ifwo$=ob$(3)andag(3)=1thenprint"ok. die ";ob$(41);" ist offen!":tu=1:goto40000
2955 ifwo$=ob$(3)thenprint"den hast du nicht dabei":goto40000
2956 ifwo$<>ob$(3)andi=41thenprint"damit klappt's leider nicht!":goto40000
2960 poke646,1:print"das geht doch nicht!":goto40000
2970 :
2980 ifi=16thenpoke646,1:input"welche kombination";co:ifco<>xxthenprint"falsch!"
2981 ifi=16andco<>xxthenpoke53281,6:goto40000
2982 poke646,3:poke53281,6:print"ist offen!"
2983 ifi=2andag(3)=0thenprint"in der ";ob$(2);" liegt ein ";ob$(3):ob(3)=14
2984 ifi=6andag(8)=0thenprint"im ";ob$(6);" ist eine ";ob$(8):ob(8)=9
2985 ifi=8andag(9)=0thenprint"in der ";ob$(8);" ist eine ";ob$(9):ob(9)=ob(8)
2986 ifi=15thenprint"in der ";ob$(15);" liegt ein ";ob$(17):ob(17)=6
2987 ifi=16thenprint"der ";ob$(16);" ist leer. pech!"
2989 ifi=33thenprint"im ";ob$(33);" steht eine ";ob$(34):ob(34)=16
2990 if i=34 then 30000
2991 ifi=45andag(46)=0thenprint"in der ";ob$(45);" ist ein ";ob$(46):ob(46)=40
2993 ifi=51andag(52)=0thenprint"im ";ob$(51);" ist ein ";ob$(52):ob(52)=ob(51)
2994 ifi=51andag(53)=0thenprint"im ";ob$(51);" ist eine ";ob$(53);:ob(53)=ob(51)
2995 ifi=47andag(48)=0thenprint"im ";ob$(47);" ist ein ";ob$(48):ob(48)=43
2996 ifi=49andag(50)=0thenprint"in der "ob$(49);" ist ein sack mit gold":ob(50)=44
2999 goto40000
3000 rem *** lies ***
3001 i=0
3010 i=i+1:ifi>65goto3040
3020 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then3050
3030 goto3010
3040 poke646,1:print"nicht vorhanden":goto40000
3050 if i=17 then 3080
3060 if i=21 then 3090
3065 if i=46 then 3100
3070 poke646,1:print"es steht nichts drauf.":goto40000
3080 printchr$(147):poke53281,1:poke646,0:printtab(15)"{down}{down}{down}{down}{down}{down}{down}der code lautet:"
3085 printtab(19)"{down}{down}56329":poke53281,11:poke646,3:forp=0to4000:next:goto1035
3090 printchr$(147):printtab(10)"der magier":printtab(10)"{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}":print
3091 print:print"1. der magier ist unsterblich. er"
3092 printtab(3)"laesst sich nicht vernichten,"
3093 printtab(3)"nur verwandeln. doch auch das"
3094 printtab(3)"hilft nur fuer kurze zeit.":print
3095 print"2. es gibt mehrere zauberworte,":printtab(3)"doch es ist immer nur eins"
3096 printtab(3)"gueltig.":print:print"3. es ist ratsam, sich in kenntnis"
3097 printtab(3)"des zauberwortes zu setzen, bevor"
3098 printtab(3)"man dem magier begegnet. {CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}":print:printtab(30)"fertig?"
3099 poke 198,0:wait 198,1:goto 1035
3100 printchr$(147):poke53281,14:poke646,1
3101 for p=1 to 4:print:next
3102 printtab$(9)"in diesem spiel lautet":printtab(12)"das zauberwort:"
3103 print:print:print:print tab(15)za$(za)
3104 forp=1to1000:next:poke53281,6:goto40000
3110 rem *** iss ***
3111 i=0
3112 i=i+1:ifi>65goto3115
3113 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then3120
3114 goto3112
3115 poke646,1:print"nicht vorhanden!":goto40000
3120 ifi=11then30000
3121 ifi=9thenq=q-2:print"du kannst jetzt eine"
3122 ifi=9thenprint"weile 2 gegenstaende mehr tragen":qm=15:ob(9)=0:goto40000
3124 poke646,1:print"ich dachte mir schon, dass du einen"
3125 print"sonderbaren geschmack hast, aber dass"
3126 print"kann man wirklich nicht essen.":forp=1to2500:goto40000
3200 rem *** trink ***
3210 rem (fuer evtl. erweiterungen)
3220 goto 1035
3300 rem *** benutze ***
3310 rem (fuer evtl. erweiterungen)
3320 goto 1035
3340 ifi=59andw$=ob$(28)thenag(28)=0
3400 rem *** verjage ***
3401 i=0
3402 i=i+1:ifi>65then3410
3404 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then3420
3406 goto 3402
3410 poke646,1:print"nicht vorhanden":poke646,3:goto40000
3420 if i=37ori=38 ori=39 ori=40 ori=59 then3429
3421 ifi=58then30000
3422 poke646,1:print"sowas kann man nicht";be$(9);"n":goto40000
3429 input"womit";w$
3430 ifi=59then3436
3431 ifi=39ori=40then3450
3432 ifw$=ob$(28)andag(28)=1orw$=ob$(48)andag(48)=1then3435
3433 ifw$=ob$(52)andag(52)=1then3435
3434 goto30000
3435 print"ok.":goto40000
3436 ifi=59thenprint"der ";ob$(59);" hat dein ";w$;" in"
3438 ifi=59thenprint"einen ";ob$(60);" verwandelt":ag(60)=1
3440 ifi=59andw$=ob$(28)thenag(28)=0
3442 ifi=59andw$=ob$(48)thenag(48)=0
3444 ifi=59andw$=ob$(53)thenag(53)=0
3446 ifi=59andw$=ob$(54)thenag(54)=0
3448 goto 40000
3450 ifw$=ob$(52)andag(52)=1orw$=ob$(48)andag(48)=1then3452
3451 goto 30000
3452 print"ok.":goto40000
3453 goto 30000
3500 rem *** druecke ***
3501 i=0
3510 i=i+1:ifi>65goto3530
3520 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then3531
3525 goto 3510
3527 ifi=10then30000
3530 poke646,1:print"nicht vorhanden!":goto40000
3531 ifi=13then30000
3532 ifi=56then3538
3533 goto 3550
3538 forp=1to9:fori=7to14:poke53281,i:nexti,p:poke53281,6
3541 poke646,7:print"du bist durch eine geheime tuer in"
3542 print"einen anderen raum gekommen":y=y-1:goto 40000
3550 poke646,1:print"da tut sich nichts!":goto40000
3600 rem *** befreie ***
3601 i=0
3610 i=i+1:ifi>65thenprint"nicht vorhanden":goto40000
3620 ifright$(ko$,(len(ob$(i))))=ob$(i)andob(i)=f%(x,y,z)then3640
3630 goto3610
3640 ifi=44ori=62then3660
3650 print"einen unsinnigen befehl fuehre ich"
3655 print"prinzipiell nicht aus!":goto40000
3660 ifi=62thenpoke646,7:print"das "ob$(62);" flieht mit dir.":ob(62)=0:ag(62)=2
3670 ifi=44thenprint"die ";ob$(44);" ist davongeflogen":ob(44)=0:ag(44)=3
3680 goto40000
3699 rem *** verwandle
3700 ifright$(ko$,6)<>ob$(58)then3720
3701 iff%(x,y,z)=ob(58)then3704
3702 iff%(x,y,z)<>ob(i)thenprint"nicht vorhanden":goto40000
3704 input"zauberspruch";za$
3705 ifza$=za$(za)thenprint"der ";ob$(58);"hat sich in luft aufgeloest"
3710 ifza$=za$(za)then40000
3715 goto 30000
3720 iff%(x,y,z)=ob(58)then30000
3722 poke646,0:print"sonst hast du keine propleme ?!":goto40000
3799 rem *** save ***
3800 printchr$(147):ii$=ti$
3805 input"filename";na$
3810 open1,1,1,na$
3815 print#1,x
3820 print#1,y
3825 print#1,z
3830 print#1,ri$
3831 print#1,q
3832 print#1,qm
3835 fori=1to65:print#1,ag(i):next
3840 fori=1to65:print#1,ob(i):next
3841 print#1,ze
3842 print#1,zw
3843 print#1,ii$
3844 print#1,za
3845 close1
3850 goto 1032
3899 rem *** verzaubere ***
3900 ifright$(ko$,6)<>ob$(58)then3720
3901 iff%(x,y,z)=ob(58)then3704
3902 iff%(x,y,z)<>ob(i)thenprint"nicht vorhanden":goto 40000
3904 input"zauberspruch";za$
3905 ifza$=za$(za)thenprint"der ";ob$(58);"hat sich in luft aufgeloest"
3910 ifza$=za$(za)then40000
3915 goto30000
3920 poke646,0:print"sonst hast du keine probleme,was?!":goto40000
4000 print"ich kann dir nur viel glueck wuenschen":goto40000
4100 poke646,1:print"{down}einen befehl bitte!":goto40000
4199 rem *** list ***
4200 i=0
4210 printchr$(147)"du hast:"
4220 i=i+1:ifi>65then4260
4230 if ag(i)=1 then print ob$(i)
4235 if ag(i)=2 then print"{down}{down}";ob$(i)
4240 goto4220
4250 :
4260 printtab(30)"{rvon}fertig?{rvof}"
4270 geta$:ifa$=""then4270
4280 printchr$(147):goto1035
4299 rem *** load altes spiel ***
4300 printchr$(147)
4305 input"filename";na$
4310 open 1,1,0,na$
4315 input#1,x
4320 input#1,y
4325 input#1,z
4330 input#1,ri$
4331 input#1,q
4332 input#1,qm
4335 for i=1to65:input#1,ag(i):next
4340 i=0
4345 input#1,ze
4350 input#1,zw
4351 input#1,ii$:ti$=ii$
4352 input#1,za
4355 close 1
4360 poke646,3:goto1032
5110 poke646,1:print"die eingangstuer ist verschlossen!":goto40000
9000 iff%(x,y,z)=1thenri$="o,r"
9010 iff%(x,y,z)=2orf%(x,y,z)=11orf%(x,y,z)=15thenri$="w,o"
9020 iff%(x,y,z)=3thenri$="w,s"
9030 iff%(x,y,z)=4thenri$="s,h"
9040 iff%(x,y,z)=5thenri$="s"
9050 iff%(x,y,z)=6thenri$="s,o"
9060 iff%(x,y,z)=7orf%(x,y,z)=16thenri$="n,w"
9070 iff%(x,y,z)=8thenri$="s,r,(n)"
9080 iff%(x,y,z)=9thenri$="n,s"
9090 iff%(x,y,z)=13thenri$="n,o"
9100 iff%(x,y,z)=10thenri$="n,o,s"
9110 iff%(x,y,z)=12thenri$="n,w,s"
9130 iff%(x,y,z)=14thenri$="n,w,(s),o"
9140 iff%(x,y,z)=33thenri$="s"
9150 iff%(x,y,z)=34thenri$="s,o"
9160 iff%(x,y,z)=35thenri$="s,w,o"
9170 iff%(x,y,z)=36thenri$="w,s,r"
9180 iff%(x,y,z)=37thenri$="n,s,o"
9190 iff%(x,y,z)=38thenri$="n,w"
9200 iff%(x,y,z)=39thenri$="n,s"
9210 iff%(x,y,z)=40thenri$="n"
9220 iff%(x,y,z)=41thenri$="n,o"
9230 iff%(x,y,z)=44thenri$="s"
9235 iff%(x,y,z)=42thenri$="w,s"
9240 iff%(x,y,z)=43thenri$="n,s"
9260 iff%(x,y,z)=45thenri$="o"
9270 iff%(x,y,z)=46 or f%(x,y,z)=47 then ri$="n,w,o"
9280 iff%(x,y,z)=48thenri$="w"
9290 iff%(x,y,z)=17thenri$="s,h"
9300 iff%(x,y,z)=18thenri$="s,o"
9310 iff%(x,y,z)=19thenri$="w,o"
9320 iff%(x,y,z)=20thenri$="w"
9330 iff%(x,y,z)=21thenri$="n,o"
9340 iff%(x,y,z)=22thenri$="n,w,o"
9350 iff%(x,y,z)=23thenri$="s,w,o"
9360 iff%(x,y,z)=24thenri$="w,h"
9370 iff%(x,y,z)=26thenri$="s,o"
9380 iff%(x,y,z)=27thenri$="n,w,s,o"
9390 iff%(x,y,z)=28thenri$="s,w"
9400 iff%(x,y,z)=29thenri$="o"
9410 iff%(x,y,z)=30thenri$="n,w,o"
9420 iff%(x,y,z)=31thenri$="n,w,o"
9810 iff%(x,y,z)=37thenri$="n,s,o"
9980 print"moegliche richtungen ";ri$;" {rvon}";ze
9990 return
10000 ifi=1thenob(2)=14:goto11000
10020 ifi=5thenob(7)=9:goto11000
10030 ifi=6thenob(8)=9:goto11000
10040 ifi=8thenob(9)=9:goto11000
10050 ifi=10thenob(11)=5:goto11000
10060 ifi=10thenob(12)=5:goto11000
10070 ifi=14thenob(16)=6:goto11000
10080 ifi=15thenob(17)=6:goto11000
10090 ifi=18thengoto11200
10100 ifi=19thengoto11300
10110 ifi=20thenob(21)=7:goto11000
10120 ifi=25thenob(26)=2:goto11000
10130 ifi=33thenob(34)=16:goto11000
10140 ifi=43thenob(44)=33:goto11000
11000 goto 40000
11200 print"hier sind jede menge buecher
11210 print"mit kyrillischen buchstaben!"
11220 forp=1to2500:next:goto1035
11300 print"der ";ob$(19);" ist verschlossen!":goto40000
29999 rem *** fehlschlag/spielende ***
30000 printchr$(147):poke646,7:pokev+21,0:poke53281,9:poke53280,9
30005 print"leider ist dir ein bedauerlicher"
30010 print"fehler unterlaufen, so dass du"
30014 print"das spiel an dieser stelle beenden"
30015 print"musst.":gosub62000
30016 fori=37to40:ifob(i)=f%(x,y,z)then30210
30017 next
30018 ifob(58)=f%(x,y,z)then30215
30019 iff%(x,y,z)=10then30230
30020 ifright$(ko$,5)=ob$(11)then30240
30021 ifright$(ko$,7)=ob$(34)then30250
30024 ifi=24ori=30thenprint"{down}{down}du hast aus dem";ob$(24);" gesehen.
30025 print"es gab eine menge zu sehen, aber was"
30030 print"du {rvon}nicht{rvof} gesehen hast, war der "
30035 printob$(39);" der dir von oben einen ziegel-"
30040 print"stein auf den kopf geworfen hat."
30044 poke646,7
30045 print"{down}du hast ";left$(ti$,2);" std.";mid$(ti$,3,2);" min. ";right$(ti$,2);"sec."
30050 print"durchgehalten."
30055 ifag(50)=1thenpr=pr+10
30060 ifag(52)=1thenpr=pr+10
30065 ifze=5thenpr=pr+30
30070 ifag(44)=3thenpr=pr+5
30075 ifag(44)=1thenpr=pr-10
30080 ifag(62)=2thenpr=pr+30
30090 ifze>90thenpr=pr-(ze-90)
30095 ifpr>100thenpr=100
30125 print"{down}das spiel wurde zu ";pr;" prozent"
30130 print"geloest."
30135 ifpr<10thenprint"ein blinder waere nicht schlechter"
30136 ifpr<10thenprint"gewesen. mein tip: ueben, ueben!!":goto30190
30140 rem
30145 ifpr<30thenprint"na ja, ";pr;" prozent sind noch nicht"
30146 ifpr<30thenprint"das gelbe vom ei.":goto30190
30150 ifpr<50thenprint"mit ";pr;"prozent bis du schon"
30151 ifpr<50thenprint"fast gut!":goto30190
30155 ifpr<70thenprint"wer es schon soweit gebracht hat, der"
30156 ifpr<70thenprint"schafft es bestimmt bald, ueber die"
30157 ifpr<70thenprint"70-prozent marke hinauszukommen.":goto30190
30160 ifpr<90thenprint"donnerwetter! ";pr;"prozent sind schon"
30161 ifpr<90thenprint"erstaunlich gut. bald bist du am ziel.":goto30190
30165 ifpr<100thenprint"ich fasse es nicht!!";pr;" prozent!!"
30166 ifpr<100thenprint"ist mein spiel doch zuleicht?"
30167 ifpr<100thenprint"aber denke daran : auch 100 prozent"
30168 ifpr<100thenprint"sind moeglich!":goto30190
30170 ifpr=100thenprint"h u n d e r t p r o z e n t i g ! ! ! "
30171 ifpr=100thenprint"diese leistung wird dir so schnell "
30172 ifpr=100thenprint"keiner nachmachen! congratulation! "
30190 print"noch ein versuch? (j/n)"
30195 geta$:ifa$=""goto30195
30200 ifa$="j"thenrestore:goto13
30205 poke53280,14:poke53281,6:poke646,14:print"{clr}ok. bis zum naechsten mal":end
30210 print"{down}der waechter hat dich getoetet!":goto30045
30215 print"der magier hat dich in einen stein"
30220 print"verwandelt!":goto30045
30230 print"{down}du bist in eine fallgrube gestuerzt":goto30045
30240 print"{down}der ";ob$(11);" war vergiftet!":goto30045
30250 print"{down}in der ";ob$(34);" war gift!":goto30045
38999 rem *** erfolg/spielende ***
39000 printchr$(147):pr=pr+15
39010 print"{down}{down}meinen herzlichen glueckwunsch"
39020 print"{down}du bist tatsaechlich aus dem haus"
39030 print"herausgekommen.":gosub61005:printchr$(147):goto30044
40000 poke646,3:forp=0to2800:next:goto1035
43000 print"die pille wirkt nicht mehr.wenn du"
43010 print"mehr als 4 sachen bei dir hast, musst"
43020 print"du erst welche verlieren.":ze=ze-1
43030 input"was willst du verlieren";gv$
43040 i=0
43050 i=i+1:ifgv$=ob$(i)andag(i)=1thenprint"in ordnung":ob(i)=f%(x,y,z)
43051 ifgv$=ob$(i)andag(i)=1thenq=q-1:ag(i)=0:goto40000
43055 ifi>65goto43060
43057 goto43050
43060 print"das hast du doch nicht!":goto40000
50000 print"{home}{down}{down}{down}{down}"
50010 printtab(10)"M",tab(38)"N"
50020 printtab(11)"M",tab(37)"N"
50030 printtab(12)"M{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}N"
50040 forp=1to9:printtab(12)"{CBM-M}",tab(36)"{CBM-G}":next
50050 printtab(12)"N{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}M"
50070 printtab(11)"N",tab(37)"M"
50080 printtab(10)"N",tab(38)"M"
50084 print
50085 iff%(x,y,z)=8thenon(tu+1)gosub52000,52500
50090 ifleft$(ri$,1)="w"ormid$(ri$,3,1)="w"orright$(ri$,1)="w"thengosub50500
50100 ifleft$(ri$,1)="o"ormid$(ri$,3,1)="o"orright$(ri$,1)="o"thengosub51500
50110 ifleft$(ri$,1)="n"ormid$(ri$,3,1)="n"orright$(ri$,1)="n"thengosub51000
50115 gosub54900
50120 return
50500 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
50510 printtab(10)"{CBM-M}M"
50520 forp=1to6:printtab(10)"{CBM-M}{CBM-M}":next
50530 printtab(10)"{CBM-M} "
50540 return
51000 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
51010 printtab(20)"{CBM-@}{CBM-@}{CBM-@}{CBM-@}"
51020 printtab(19)"{CBM-M}M{CBM-@}{CBM-@}N{CBM-G}
51030 forp=1to3:printtab(19)"{CBM-M}{CBM-M} {CBM-G}{CBM-G}":next
51040 printtab(19)"{CBM-M}{CBM-M}{CBM-T}{CBM-T}{CBM-G}{CBM-G}"
51050 printtab(19)"{CBM-M}N M{CBM-G}"
51055 printtab(20)" "
51060 return
51500 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
51510 printtab(37)"N{CBM-G}"
51520 fori=1to6:printtab(37)"{CBM-G}{CBM-G}":next
51530 printtab(37)" {CBM-G}"
51540 return
51600 iff%(x,y,z)=14thengosub55000
52000 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
52010 printtab(20)"{CBM-@}{CBM-@}{CBM-@}{CBM-@}"
52020 fori=1to6:printtab(19)"{CBM-M} {CBM-M}":next
52030 return
52500 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
52510 printtab(20)"{CBM-@}{CBM-@}{CBM-@}{CBM-@}"
52520 printtab(19)"{CBM-M} {CBM-M}M"
52530 fori=1to 5:printtab(19)"{CBM-M} {CBM-M} {CBM-G}":next
52540 printtab(20)" M{CBM-G}"
52550 return
54900 iff%(x,y,z)=14thengosub55000
54901 iff%(x,y,z)=10orf%(x,y,z)=48thenprint"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"tab(33)"W"
54902 iff%(x,y,z)=13orf%(x,y,z)=7orf%(x,y,z)=15orf%(x,y,z)=33thengosub55140
54903 iff%(x,y,z)=12orf%(x,y,z)=6thengosub55200
54904 iff%(x,y,z)=6orf%(x,y,z)=40orf%(x,y,z)=44then55221
54905 iff%(x,y,z)=3thengosub55240
54906 iff%(x,y,z)=12thengosub55250
54907 iff%(x,y,z)=4orf%(x,y,z)=24thengosub55276
54908 iff%(x,y,z)=5orf%(x,y,z)=7orf%(x,y,z)=48thengosub55300
54909 iff%(x,y,z)=9orf%(x,y,z)=7orf%(x,y,z)=16thengosub55306
54910 iff%(x,y,z)=8orf%(x,y,z)=36thengosub55264
54911 iff%(x,y,z)=43orf%(x,y,z)=ob(51)thengosub55306
54912 iff%(x,y,z)=33thengosub55320
54913 iff%(x,y,z)=9thengosub55400
54914 iff%(x,y,z)=1thengosub55416
54915 iff%(x,y,z)=17thengosub55426
54990 return
55000 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55010 printtab(30)"{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}"
55020 printtab(29)"{CBM-M}M M"
55030 printtab(30)"M{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-G}"
55040 printtab(31)"{CBM-G} {CBM-G}"
55050 printtab(30)"M{CBM-G} {CBM-G}"
55060 printtab(31)"{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}"
55070 ifob(2)=14thenprint"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"tab(33)"O{CBM-Y}P"
55080 ifob(2)=14thenprinttab(33)"{CBM-Y}{CBM-Y}{CBM-Y}"
55090 ifob(3)=14thenprint"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55100 ifob(3)=14thenprinttab(32)"{CBM-M}M M"
55110 ifob(3)=14thenprinttab(33)"MO{CBM-Y}{CBM-Y}{CBM-G}"
55120 ifob(3)=14thenprinttab(34)"{CBM-T}{CBM-T}{CBM-T}"
55130 return
55140 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55150 printtab(13)"{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}"
55160 printtab(12)"N N{CBM-G}
55170 printtab(11)"{CBM-M}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-G}{CBM-G}"
55180 printtab(11)"{CBM-M} {CBM-G}"
55190 return
55200 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55202 ifob(16)=0orf%(x,y,z)=12thenprinttab(14)"O{CBM-Y}{CBM-Y}{CBM-Y}P"
55204 ifob(16)=0orf%(x,y,z)=12thenprinttab(14)"{CBM-H} {CBM-N}"
55206 ifob(16)=0orf%(x,y,z)=12thenprinttab(14)"L{CBM-P}{CBM-P}{CBM-P}{SHIFT-@}"
55210 ifob(16)=6andf%(x,y,z)<>12thenprinttab(14)"UCI"
55212 ifob(16)=6andf%(x,y,z)<>12thenprinttab(14)"BWB"
55214 ifob(16)=6andf%(x,y,z)<>12thenprinttab(14)"JCK"
55216 return
55220 ifob(17)=6orob(46)=40orob(50)=44then55232
55221 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55222 printtab(31)"{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}"
55224 printtab(30)"{CBM-N}M M"
55226 printtab(30)"{CBM-N} O{CBM-Y}{CBM-Y}{CBM-Y}P"
55228 printtab(30)" ML{CBM-P}{CBM-P}{CBM-P}{SHIFT-@}"
55230 return
55232 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55234 printtab(31)"O{CBM-Y}{CBM-Y}{CBM-Y}P"
55236 printtab(31)"L{CBM-P}{CBM-P}{CBM-P}{SHIFT-@}"
55238 goto 55224
55240 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55242 printtab(20)"O{CBM-Y}{CBM-Y}P{CBM-Y}{CBM-Y}P"
55244 printtab(20)"{CBM-H} {CBM-N} {CBM-N}"
55246 printtab(20)"L{CBM-P}{CBM-P}{SHIFT-@}{CBM-P}{CBM-P}{SHIFT-@}"
55248 return
55250 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55252 printtab(37)"N{CBM-G}"
55254 printtab(37)"{CBM-G}{CBM-G}"
55256 printtab(37)"{CBM-G}{CBM-G}"
55258 printtab(37)"{CBM-G}{CBM-G}"
55260 printtab(37)"M{CBM-G}"
55262 return
55264 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55266 printtab(28)"NO{CBM-Y}{CBM-Y}{CBM-Y}PM"
55268 printtab(27)"NN{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}MM"
55270 printtab(26)"N O{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}P M"
55272 printtab(26)"{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}"
55274 return
55276 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55278 printtab(32)"O{CBM-Y}P"
55280 printtab(32)"{CBM-H} {CBM-N}"
55282 printtab(32)"{CBM-H} {CBM-N}"
55284 printtab(31)"N{CBM-Y}{CBM-Y}{CBM-Y}M"
55288 printtab(30)"N{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}M"
55290 printtab(30)"O{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}P"
55292 printtab(29)"N{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}M"
55294 printtab(29)"O{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}P"
55296 printtab(29)"{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}"
55298 return
55300 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55302 fori=1to7:printtab(14)"O{CBM-Y}{CBM-Y}P":next
55304 return
55306 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}"
55308 printtab(31)"{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}L"
55310 printtab(30)"N{CBM-H} {CBM-N} {CBM-N}
55312 fori=1to7:printtab(30)"{CBM-H}{CBM-H} {CBM-N} {CBM-N}":next
55314 printtab(30)"{CBM-H}L{CBM-P}{SHIFT-@}{CBM-P}{CBM-P}{SHIFT-@}"
55316 printtab(30)"ML{CBM-P}{SHIFT-@}{CBM-P}{CBM-P}{SHIFT-@}"
55318 return
55320 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55322 printtab(13)" {CBM-P}{CBM-P} "
55324 printtab(13)"{CBM-M}UI{CBM-G}"
55326 printtab(13)"{CBM-M}[[{CBM-G}"
55328 printtab(13)"{CBM-M}[[{CBM-G}"
55330 return
55400 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55402 printtab(12)" {CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}"
55404 printtab(12)"N N{CBM-H}"
55406 printtab(12)"O{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}P {CBM-H}"
55408 printtab(12)"{CBM-H}UCCI{CBM-N} {CBM-G}"
55410 printtab(12)"{CBM-H}JCCK{CBM-N}N"
55412 printtab(12)"{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}"
55414 return
55416 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
55418 printtab(15)" {CBM-Q}C{CBM-W} "
55420 printtab(15)"N{CBM-Q}C{CBM-W}M "
55422 printtab(15)"{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}"
55424 return
55426 print"{home}{down}{down}{down}{down}"
55428 printtab(15)"{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}"
55430 printtab(15)"M{CBM-Q}C{CBM-W}N"
55432 forp=1to12:printtab(15)" {CBM-Q}C{CBM-W}":next
55434 return
60400 si=54272
60405 for dy=1 to 3
60410 la=10
60420 for hi=70 to 100 step 2
60430 pokesi+24,la
60440 pokesi+6,15*16
60450 pokesi+1,hi
60460 pokesi+4,33
60470 la=la+1
60480 ifla>14thenla=15
60490 next hi
60500 next dy
60510 pokesi+4,0:pokesi+24,0
60520 return
61005 si=54272:pokesi+24,15:pokesi+1,0
61007 wa=45
61008 pokesi+5,255:pokesi+6,255
61009 pokesi+4,17:pokesi+20,255:pokesi+18,33:pokesi+12,8:pokesi+13,0
61010 forwi=1to4:form=0to95step3
61011 pokesi+8,f(m+1):pokesi+7,f(m+2)
61012 poke si+11,33
61013 if f(m)=0 then au=0:goto 61015
61014 au=1
61015 if wi>2 thenpoke si+1,f(m):pokesi+15,f(m)+au:wa=28
61016 poke646,f(m):print"{home}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}gratuliere!"
61017 fori=1towa:next:pokesi+11,0
61018 nextm,wi:fori=1to500:next
61019 pokesi+24,0:pokesi+4,0:return
62000 m=-2
62002 pokesi+24,15:pokesi+2,13:pokesi+3,15
62004 pokesi+5,3*16+15:pokesi+6,9
62006 pokesi+12,16+6:pokesi+13,4*16+4
62008 for w=1 to 3
62010 for n=0 to 15 step 2
62012 pokesi+8,fa(n):pokesi+7,fa(n+1)
62014 ifw>1thenm=m+2:pokesi+1,fb(m):pokesi,fb(m+1)
62016 poke si+11,17
62018 if w>1 thenpoke si+4,17
62020 for p=1 to 125:next p
62022 poke si+11,0
62024 next n
62026 next w
62028 poke si+4,0:poke si+24,0
62030 return
<< zurück zu Das Haus des Magiers
